TOPLA işlevi


TOPLA işlevi

Şunlara Uygulanır: Excel 2016 , Excel 2013 , Excel 2010 , Excel 2007 , Mac için Excel 2016 , Diğer...
 

Matematik ve trigonometri işlevlerinden biri olan TOPLA işlevi, değerleri toplar. Ayrı değerler, hücre başvuruları, aralıklar veya bunların üçünü birlikte kullanabilirsiniz.

Örneğin:

  • =TOPLA(A2:A10)

  • =TOPLA(A2:A10, C2:C10)

 

Bu video, Excel 2013'te sayıları toplama adlı eğitim kursunun bir bölümüdür.

 
Söz dizimi:

TOPLA(sayı1,[sayı2],...)

Bağımsız değişken adı

Açıklama

sayı1    (Gerekli)

Toplamak istediğiniz ilk sayı. Bu 4 gibi bir sayı, B6 gibi bir hücre başvurusu veya B2:B8 gibi bir hücre aralık olabilir.

sayı2-255    (İsteğe bağlı)

Bu, toplamak istediğiniz ikinci sayıdır. Bu şekilde, en çok 255 sayı belirtebilirsiniz.

 
Durum Çubuğu’nda gösterilen Hızlı Toplam

Bir hücre aralığının Toplamını hızlıca almak istiyorsanız aralığı seçip Excel penceresinin sağ alt kısmına bakmanız yeterlidir.

Bir hücre aralığı seçip Durum Çubuğu’na bakma ekran görüntüsü
Durum Çubuğu

Bu, Durum Çubuğu’dur ve ister tek bir hücre ister birden fazla hücre olsun seçtiğiniz hücrelerle ilgili bilgileri gösterir. Durum Çubuğu’na sağ tıklarsanız belirleyebileceğiniz tüm seçeneklerin gösterildiği bir özellik iletişim kutusu açılır. Öznitelikleri işaretlediyseniz seçtiğiniz aralığın değerleri de gösterilir. Durum Çubuğu hakkında daha fazla bilgi edinin.

 
Otomatik Toplam Sihirbazı’nı kullanma

Çalışma sayfanıza bir TOPLA formülü eklemenin en kolay yolu Otomatik Toplam Sihirbazı’nı kullanmaktır. Toplamak istediğiniz aralığın hemen üst veya altındaki boş bir hücreyi seçin ve Şerit’teki Giriş veya Formül sekmelerinde Otomatik Toplam > Toplam’a basın. Otomatik Toplam Sihirbazı toplanacak aralığı otomatik olarak algılar ve sizin yerinize formülü oluşturur. Toplanacak aralığın sol veya sağındaki bir hücreyi seçtiğinizde yatay olarak da çalışabilir. Bu işlev bitişik olmayan aralıklarda çalışmaz. Bu konuyu daha sonra ele alacağız.

Otomatik olarak bir Topla formülü oluşturmak için Otomatik Toplam Sihirbazı’nı kullanabilirsiniz.  Aralığın üstünden/altından veya solundan/sağından toplamak için bir aralık seçin ve Şerit’teki Formül sekmesine gidip Otomatik Toplam ve TOPLAM’ı seçin.
Bitişik aralıkları hızlıca toplamak için Otomatik Toplam Sihirbazı’nı kullanma

Otomatik Toplam iletişim kutusu aşağıdakiler gibi diğer yaygın işlevleri de seçmenizi sağlar:

  • Ortalama

  • Sayıları say

  • Mak

  • Min

  • Diğer işlevler

    Dikey Otomatik Toplam

    B6 hücresinde Otomatik Toplam Topla formülü gösterilir: =TOPLA(B2:B5)
    Dikey Otomatik Toplam

Otomatik Toplam Sihirbazı, toplanacak aralık için otomatik olarak B2:B5 hücrelerini algıladı. Onaylamak için Enter tuşuna basmanız yeterlidir. Daha fazla hücre eklemeniz/hariç tutmanız gerekirse istediğiniz seçimi yapana kadar Shift Tuşu > istediğiniz ok tuşuna basılı tutun ve işiniz bitince Enter tuşuna basın.

IntelliSense işlev kılavuzu: TOPLA(sayı1,[sayı2], …) işlevin altındaki kayan etiket, IntelliSense kılavuzudur. TOPLA’ya veya işlev adına tıkladığınızda ad, sizi söz konusu işlevin Yardım konusuna götüren mavi bir köprüye dönüşür. Ayrı işlev öğelerine tıklarsanız formüldeki temsil ettikleri bölümler vurgulanır. Bu durumda yalnızca B2:B5 vurgulanır, bu formülde yalnızca bir sayı başvurusu bulunur. IntelliSense etiketi herhangi bir işlevde görüntülenir.

Yatay Otomatik Toplam

D2 hücresinde Otomatik Toplam Topla formülü gösterilir: =TOPLA(B2:C2)
Yatay Otomatik Toplam
 
Bitişik olmayan hücreleri toplama
Bitişik olmayan aralıklarla TOPLA işlevini kullanma.  C8 hücresindeki formül: =TOPLA(C2:C3,C5:C6). Formülün =TOPLA(Hafta1,Hafta2) olması için Adlandırılmış Aralıklar da kullanabilirsiniz.
Bitişik olmayan hücreleri toplama

Otomatik Toplam Sihirbazı, genel olarak yalnızca bitişik aralıklarla çalışır. Toplama aralığınızda boş satır veya sütunlar varsa Excel ilk boşlukta durur. Bu durumda aralıkları tek tek ekleyerek seçime göre TOPLAMA yapmanız gerekir. Bu örnekte B4 hücresinde verileriniz olsaydı Excel bir bitişik aralık algılayacağı için =TOPLA(C2:C6) formülünü oluştururdu.

Ctrl+Sol Tıklama ile bitişik olmayan birden fazla aralığı hızlıca seçebilirsiniz. İlk olarak “=TOPLA(“, yazıp farklı aralıkları seçin. Excel virgül ayıracını sizin yerinize otomatik olarak ekleyecektir. İşiniz bittiğinde Enter tuşuna basın.

İPUCU: TOPLA işlevini bir hücreye hızlıca eklemek için ALT+= tuşlarını kullanabilirsiniz. Daha sonra tek yapmanız gereken aralıklarınızı seçmektir.

Not: Excel’in farklı işlev aralıklarını renkli olarak nasıl vurguladığını ve renklerin formülle nasıl eşleştiğini görebilirsiniz. Yani C2:C3 bir renk ve C5:C6 başka bir renk görünür. Başvurulan aralık bir çalışma sayfasında veya çalışma kitabında olmadığı sürece Excel bu işlemi tüm işlevlerde gerçekleştirir. Yardımcı teknolojiyle gelişmiş erişilebilirlik için “Hafta1”, “Hafta2” vb. gibi Adlandırılmış Aralıklar kullanabilir ve sonra formülünüzde bunlara başvurabilirsiniz:

=TOPLA(Hafta1,Hafta2)

 
En İyi Yöntemler

Bu bölümde bazı en iyi TOPLA işlevleriyle çalışma yöntemleri ele alınacaktır. Bunların çoğunu diğer işlevlerle çalışırken de uygulayabilirsiniz.

=1+2 veya =A+B Yöntemi – =1+2+3 veya =A1+B1+C2 girerek tamamen doğru sonuçlar alabilseniz de bu yöntemler bazı nedenlerle hataya eğilimlidir:
  1. Yazım hataları - Şunun gibi daha fazla ve/veya daha büyük veriler girmeye çalıştığınızı düşünün:

    • =14598,93+65437.90+78496,23

    Sonra da girişlerinizin doğru olduğunu doğrulamaya çalıştığınızı düşünelim. Bu değerleri tek tek hücrelere yerleştirmek ve bir TOPLA formülü kullanmak daha kolaydır. Ek olarak bu değerleri hücrelerde biçimlendirebilir, böylece formülde daha okunabilir olmalarını sağlayabilirsiniz.

    Değerleri doğrudan formüllere yazmak yerine TOPLA işlevini kullanın.  D5 hücresindeki formül =TOPLA(D2:D4)
  2. Sayı yerine metinlere başvurulduğunda oluşan #DEĞER! hataları

    Şunun gibi bir formül kullanırsanız:

    • =A1+B1+C1 veya =A1+A2+A3

    Kötü formül yapısı örneği.  D2 hücresindeki formül: =A2+B2+C2

    Başvurulan hücrelerde sayısal olmayan (metin) değerler bulunuyorsa formülünüz bozulabilir. Bu durumda bir #DEĞER! hatası döndürülür. TOPLA işlevi metin değerlerini yok sayar ve size yalnızca sayısal değerlerin toplamını verir.

    Doğru formül yapısı.  =A2+B2+C2 yerine D2 hücresindeki formül şu şekildedir: =TOPLA(A2:C2)
  3. Satır veya sütun silme nedeniyle oluşan #BAŞV! hatası

    Bir sütunun silinmesi nedeniyle oluşan #BAŞV! hatası.  Formül =A2+#BAŞV!+B2 olarak değiştirildi

    Bir satır veya sütun silerseniz formül, silinen satırı hariç tutacak şekilde güncelleştirilmez ve bir #BAŞV! hatası döndürür, ancak TOPLA işlevi otomatik olarak güncelleştirilir.

    TOPLA işlevi eklenen veya silinen hücre satır ve sütunlara göre otomatik olarak ayarlanır
  4. Formüller satır veya sütun eklendiğinde başvuruları güncelleştirmez

    Satır eklerseniz =A+B+C formülleri güncelleştirilmez

    Bir satır veya sütun eklerseniz formül, eklenen satırı içerecek şekilde güncelleştirilmez, ancak TOPLA işlevi otomatik olarak güncelleştirilir (formülde başvurulan aralığın dışında olmadığınız sürece). Bu, özellikle formülün güncelleştirilmesini bekliyorsanız ancak formül güncelleştirilmiyorsa önemlidir. Bu durumda fark edemeyebileceğiniz eksik sonuçlar ortaya çıkabilir.

    Bir sütun eklendiğinde =TOPLA(A2:C2) formülünden =TOPLA(A2:D2) formülüne kadar otomatik olarak genişleyen bir TOPLA formülünün gösterildiği örnek
  5. Tek tek Hücre Başvuruları ve Aralıkları olan TOPLA işlevi karşılaştırılması

    Şunun gibi bir formül kullanırsanız:

    • =TOPLA(A1,A2,A3,B1,B2,B3)

    Aynı nedenlerle başvurulan aralıkta satır eklerken veya silerken aynı derece hata yapma ihtimaliniz olur. Şunun gibi tek tek aralıklar kullanmak çok daha iyidir:

    • =TOPLA(A1:A3,B1:B3)

    Bu işlev satır eklediğinizde veya sildiğinizde değerleri güncelleştirir.

 
TOPLA ile Matematiksel İşleçleri kullanma
  1. Topladığınız hücre aralığına bir Yüzde İndirimi uygulamak istediğinizi varsayalım.

    TOPLA ile İşleçleri kullanma.  B16 hücresindeki formül =TOPLA(A2:A14)*-%25.  -%25, =TOPLA(A2:A14)*E2 gibi bir hücre başvurusu olsaydı formül düzgün oluşturulurdu
    • =TOPLA(A2:A14)*-%25

    Bu işlev size toplanan aralığın %25’ini verir, ancak bu şekilde değeri doğrudan formüle yazarsanız ve daha sonra değiştirmeniz gerekirse bulması zor olabilir. %25 değerini bir hücreye koyup bu hücreye başvurmanız çok daha iyi olur. Böylece değer açıkta görünür ve kolayca değiştirilebilir, örneğin:

    • =TOPLA(A2:A14)*E2

    Çarpmak yerine bölmek için “*” simgesini “/” ile değiştirmeniz yeterlidir: =TOPLA(A2:A14)/E2

  2. Bir TOPLA işlevine değer eklemek veya işlevden değer çıkarmak

    i. + veya - kullanarak bir Topla işlevine kolayca değer ekleyebilir veya işlevden değer çıkartabilirsiniz, örneğin:

    • =TOPLA(A1:A10)+E2

    • =TOPLA(A1:A10)-E2

 
Diğer işlevlerle TOPLAMA
  1. TOPLA işlevini diğer işlevlerin tamamıyla kullanabilirsiniz. Aşağıda aylık ortalamayı hesaplayan bir örnek verilmiştir:

    TOPLA işlevini diğer işlevlerle kullanma.  M2 hücresindeki formül: =TOPLA(A2:L2)/BAĞ_DEĞ_DOLU_SAY(A2:L2).  Not: Mayıs-Kasım sütunları anlaşılırlık için gizlenmiştir.
    • =TOPLA(A2:L2)/BAĞ_DEĞ_DOLU_SAY(A2:L2)

  2. A2:L2 TOPLAMINI A2:L2’deki boş olmayan hücre sayısına böler (Mayıs ile Aralık arası boştur).

 
Birden fazla çalışma sayfasında toplama yapmak için 3B TOPLA
  1. Bazen birden fazla çalışma sayfasındaki belirli bir hücreyi toplamanız gerekir. Her sayfaya ve hücreye tıklayarak hücre değerlerini toplamak için yalnızca “+” kullanmak isteyebilirsiniz, ancak bu işlem yorucudur ve hata eğilimlidir.

    • =Sayfa1!A1+Sayfa2!A1+Sayfa3!A1

    Bunu bir 3B veya 3 Boyutlu TOPLA ile çok daha kolay gerçekleştirebilirsiniz:

    3B Topla - D2 hücresindeki formül: =TOPLA(Sayfa1:Sayfa3!A2)
    • =TOPLA(Sayfa1:Sayfa3!A1)

    Bu formül Sayfa 1’den Sayfa 3’e kadar tüm sayfalardaki A1 hücrelerini toplar.

    Bu özellikle her ay için bir sayfanız varsa (Ocak-Aralık) ve değerleri bir özet sayfasında toplamanız gerekiyorsa yararlıdır.

    Adlandırılmış Sayfalardaki 3B TOPLA işlevi.  D2 hücresindeki formül: =TOPLA(Ocak:Aralık!A2)
    • =TOPLA(Ocak:Aralık!A2)

    Bu formül Ocak’tan Aralık’a kadar tüm sayfalardaki A2 hücresini toplar.

    NOTLAR : Çalışma sayfalarınızın adlarında boşluk varsa (ör. “Ocak Satışları”) formülde sayfa adlarına başvururken bir kesme işareti kullanmanız gerekir. İlk çalışma sayfası adından ÖNCEKİ ve son çalışma sayfasından SONRAKİ kesme işaretine dikkat edin.

    • =TOPLA(‘Ocak Satışları:Aralık Satışları’!A2)

    3B yöntemi ORTALAMA, MİN ve MAK gibi diğer işlevlerle de çalışır:

    • =ORTALAMA(Sayfa1:Sayfa3!A1)

    • =MIN(Sayfa1:Sayfa3!A1)

    • =MAK(Sayfa1:Sayfa3!A1)

 
Sık Karşılaşılan Sorunlar

Sorun

Nerede sorun çıktı?

TOPLA işlevim sonucu değil, ##### simgelerini gösteriyor.

Sütun genişliklerinizi kontrol edin. ##### simgeleri genel olarak bir sütunun sonucu gösteremeyecek kadar dar olduğu anlamına gelir.

TOPLA işlevim sonucu değil, formülü gösteriyor.

Hücrenin metin olarak biçimlendirilmediğini doğrulayın. Söz konusu hücre veya aralığı seçin ve Hücreleri Biçimlendiriletişim kutusunu açmak için Ctrl+1 tuşlarını kullanın, sonra da Sayı sekmesine tıklayıp istediğiniz biçimi seçin. Hücre metin olarak biçimlendirildiyse ve siz biçimi değiştirdikten sonra değişmezse, biçimin değişmesini zorlamak için F2 > Enter tuşlarını kullanmanız gerekebilir.

TOPLA işlevim güncelleştirilmiyor.

Hesaplama’nın Otomatik olarak ayarlandığından emin olun. Formül sekmesindeHesaplama Seçenekleri’ne gidin. Çalışma sayfasının hesaplama yapmasını zorlamak için F9 tuşunu da kullanabilirsiniz.

Bazı değerler eklenmez.

Yalnızca işlev başvurusundaki veya aralıktaki sayısal değerler toplanabilir. Boş hücreler, DOĞRU gibi mantıksal değerler veya metinler yoksayılır.

Beklenen sonuç yerine #AD? hatası görüntülenir.

Bu, genellikle bir formülün yanlış yazıldığı anlamına gelir (=TOPLA(A1:A10) yerine, =topl(A1:A10) gibi).

 
Sık Sorulan Sorular
  1. Yalnızca sayıları Toplamak/Çıkarmak/Çarpmak/Bölmek istiyorum - Excel’de Temel Matematik İşlemleri veya Excel’i hesap makineniz olarak kullanma başlıklı video serisine göz atın.

  2. Nasıl daha fazla/az ondalık basamak görüntüleyebilirim? - Sayı biçiminizi değiştirebilirsiniz. Söz konusu hücre veya aralığı seçin veHücreleri Biçimlendir iletişim kutusunu açmak için Ctrl+1 tuşlarını kullanın, sonra da Sayı sekmesine tıklayıp istediğiniz biçimi seçin.

  3. Saatleri nasıl toplayabilirim? Saatleri toplayıp çıkarabilirsiniz. Örneğin, 08:00 - 24:00 arasındaki farkı hesaplamak için =("24:00"-"08:00")*24 kullanın Excel’in saatleri günün bir parçası olarak hesapladığını unutmayın; bu nedenle toplam saatleri almak için değeri 24 ile çarpmanız gerekir. Atanan görevlerdeki saatler gibi saatleri topluyorsanız yalnızca toplama yapabilirsiniz; 24 ile çarpmanıza gerek yoktur. Kullandığımız ilk örnekte, başlangıçtan sona kadar öğle arası hariç toplam saati hesaplamak için =((B2-A2)+(D2-C2))*24kullanırız. İkinci örnekte yalnızca saat toplamına ihtiyacımız olduğundan =TOPLA(A6:C6) kullanırız.

    Saatleri hesaplama
  4. Tarihler arasındaki farkı nasıl hesaplayabilirim? Tarihleri saatler gibi toplayıp çıkarabilirsiniz. İki tarih arasındaki gün sayısını hesaplamak için kullanabileceğiniz oldukça yaygın bir örnek aşağıda verilmiştir. =B2-A2 formülü kadar basittir. Tarih ve Saatler ile birlikte çalışırken dikkat edilmesi gereken nokta, Bitiş Tarihi/Saati ile başlayıp bu değerden Başlangıç Tarihini/Saatini çıkarmanız gerektiğidir.

    Tarihler arasındaki farkları hesaplama

    Tarihlerle çalışmanın diğer yolları için bkz.: İki tarih arasındaki gün sayısını hesaplama.


Bu makaleyi yararlı buldunuz mu?